// una clase es un conjunto de propiedades y metodos

package  {
   
    import utiles.Dibujo;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import gs.*;
    import gs.easing.*;
	
   
    public class ClaseInicio extends Sprite {
        //defino las variables
        private var cuadrosTotal : uint = 8;
        private var ancho : uint = 200;
		private var alto : uint = 300;
        private var holder : Sprite; //variable de instancia que puede ser accedida de cualquier parte de la instancia, vive para toda la instancia
        private var actual : Sprite; // guarda
        private var posiciones : Array = [
            [-315, -155], [-105, -155], [+105, -155], [+315, -155],
            [-315, +155], [-105, +155], [+105, +155], [+315, +155]
            ];
       
       
       
        public function ClaseInicio () : void { //funcion constructora que 
            creaFondo();
			creaPanel();
		
			//evento para controlar la posicion del mouse
			addEventListener(Event.ENTER_FRAME, loop);
        }
       
			
        private function creaPanel () : void {
            holder = new Sprite();
            addChild(holder);
            holder.x = stage.stageWidth/2;
            holder.y = stage.stageHeight/2;
            holder.z = 600;
           
            for (var i:uint=0; i<cuadrosTotal; i++) {
                var cuadro : Sprite = Dibujo.forma(Dibujo.CUADRO, {centered:true, width:ancho, height:alto, fillColor:0x75d900});
                holder.addChild(cuadro);  
                cuadro.name = ""+i;
                cuadro.x = posiciones[i][0];
                cuadro.y = posiciones[i][1]; //variable que vive solo dentro de esta funcion o sea global....variable local
				cuadro.buttonMode=true; //indico que el sprite se comporte como un boton
				
				//evento para los cuaros
				cuadro.addEventListener(MouseEvent.MOUSE_OVER, onOver);
				cuadro.addEventListener(MouseEvent.MOUSE_OUT, onOut);
				cuadro.addEventListener(MouseEvent.CLICK, onClick);
            }
        }
		
		
		       	// fondo del escenario
		function creaFondo (): void {
			var cuadro : Sprite = Dibujo.forma (Dibujo.CUADRO, {width:550, height:400});
			addChild(cuadro);
		}
		
		
		//funciones para controlar el tamaño de los cuadros
		function amplia(cuadro:Sprite):void{
			actual = cuadro; //dejo guardado que este cuadro esta ne primer plano
						
			holder.setChildIndex(cuadro, cuadrosTotal-1); // hace que s eponga por sobre los demas cuadros
			TweenMax.to(cuadro, .75, {ease:Back.easeInOut, x:0, y:0, z:-250, scaleX:2, scaleY:2, dropShadowFilter:{blurX:20, blurY:20, distance:0, alpha:1}}); //amplia cuadros
		}
			
		function reduce(cuadro:Sprite):void{
			actual = null; // indica que no hay nada en primer plano
			
			var indice : uint = int(cuadro.name); // convierte cadena a numero
			var posX : Number = posiciones[indice][0];
			var posY : Number = posiciones[indice][1];
			
			holder.setChildIndex(cuadro, cuadrosTotal-1); // hace que se ponga por sobre los demas cuadros
			TweenMax.to(cuadro, .35, {ease:Back.easeIn, x:posX, y:posY, z:0, scaleX:1, scaleY:1, dropShadowFilter:{blurX:0, blurY:0}}); //amplia cuadros
		}
		
		
		//funciones para controlar los events de los cuadros
		function onOver (e:MouseEvent):void{
			var cuadro:Sprite = Sprite(e.target); //guardo el valor de quien dispara la funcion
			TweenMax.to(cuadro, .10, {tint:0xff0066});
		}
			
			
		function onOut (e:MouseEvent):void{
			var cuadro:Sprite = Sprite(e.target); //guardo el valor de quien dispara la funcion
			if (actual!= cuadro){ // si actual es distinto a cuadro, se mantiene color base
				TweenMax.to(cuadro, 1, {removeTint:true});
			} else {
				TweenMax.to(cuadro, 1, {tint:0xff0066}); //sino se pinta de rosado
			}
		}
			
			
		function onClick (e:MouseEvent):void{
			var cuadro:Sprite = Sprite(e.target); //guardo el valor de quien dispara la funcion
			if (actual == null){ // si no hay nada delante
				amplia(cuadro);
			} else if (actual == cuadro){ // si el cuadro que clica esta encima, vuelve a su lugar
				reduce(cuadro);
			} else { // si el cuadro que clica esta encima, vuelve a su lugar
				reduce(actual);
				amplia(cuadro);
			}
		}
											
										
		
		// funcion que controla el giro del contenedor y relacionado con evento
		function loop (e:Event): void {
			//trace(mouseX);
			var distX:Number=mouseX/stage.stageWidth;
			var distY:Number=mouseY/stage.stageHeight;
			
			var rangoX:Number=50; //valores de angulo
			var rangoY:Number=80;
			
			var rotX: Number= -rangoX + (rangoX*2*distY);
			var rotY: Number= -rangoY + (rangoY*2*distX);
			
			TweenMax.to(holder, 1, {rotationX:rotX, rotationY:rotY}); // entre llaves propiedad y valor con :
			
		}
    }
}